TITLE:
Simulation Code for Tucker-Drob, Harden, & Turkheimer(2009; Behavior Genetics)

ANALYZING MODEL- LINEAR PSYCHOMETRIC PORTION, INTERACTIVE BIOMETRIC PORTION

DATA:
FILE IS "C:\Users\etuck\Desktop\
Mplus Simulation Code\xxxlist.dat"; !READ IN LIST OF GENERATED DATASETS

TYPE IS MONTECARLO;


DEFINE:
!CREATE COMPOSITE SCORES
iq1 = q1 + r1 + s1;
iq2 = q2 + r2 + s2;


VARIABLE:

!NAMES APPEAR IN ORDER INDICATED BY OUTPUT OF GENERATING MODEL
NAMES ARE 
q1
r1
s1
q2
r2
s2
x
cat;

USEVARIABLES ARE
x
iq1
iq2;
CLASSES = CG (2); !TWO GROUP MODEL
KNOWNCLASS = CG (Cat=1 Cat=2); !1=MZ 2=DZ

CONSTRAINT IS x; !COVARIATE USED AS A CONSTRAINT FOR GXE

ANALYSIS:
TYPE = MIXTURE;
MODEL IS NOCOVARIANCES;

MODEL:
%OVERALL%

!COMPOSITE SCORE INTECEPTS & RESIDUAL VARIANCES
[iq1*0] (i1);  [iq2*0] (i1);
iq1@0; iq2@0;

!BIOMETRIC COMPONENTS 
!GENETIC FACTORS
a1 BY iq1*.8 (j2);
a2 BY iq1@0;

!SHARED ENVIRONMENT
c BY iq1*.3 (j3);
c BY iq2*.3 (j3);

!NONSHARED ENVIRONMENT
e1 BY iq1*.5 (j4);
e2 BY iq2*.5 (j4);

!BIOMETRIC COMPONENTS HAVE UNIT VARIANCES
a1@1; a2@1; c@1; e1@1; e2@1;
[a1@0 a2@0 c@0 e1@0 e2@0 x@0];

!FAMILY LEVEL COVARIATE
x@1;
iq1 on x*.2(my);
iq2 on x*.2(my);

!GENETIC FACTORS ARE ISOMORPHIC FOR MZ TWINS
a1 WITH a2@0;
iq2 on a1*.8(j2);
iq2 on a2@0;

%cg#1%

%cg#2%
iq2 on a1@0;
iq2 on a2*.8(j2); !DIFFERENT GENETIC FACTORS FOR DZ TWINS
a1 WITH a2@.5; !GENETIC FACTORS CORRELATE AT .5 FOR DZ TWINS

MODEL CONSTRAINT:
!SPECIFY COVARIATE(X) BY A, C, & E INTERACTIONS

new(aa0*.5 aa1*0 cc0*.5 cc1*0 ee0*.5 ee1*0);

j2=(aa0+aa1*x);
j3=(cc0+cc1*x);
j4=(ee0+ee1*x);

OUTPUT: SAMPSTAT STANDARDIZED;