**Sample M*plus* Scripts**

The sample M*plus* scripts that follow were all produced according to the general framework represented by Equation 5 in the article, also reproduced here:

Y*w,m,p,n*= *w* + *w*∙Fc,*n* + *m*∙*w*∙F*n* + *p*∙*w*∙FT*,n* + u*w,p,m,n* . (Eq. S1)

The subscript *w* represents the measure, the subscript/coefficient *m* represents the presence or absence of the manipulation (typically 0 or 1; 0 = not present, 1 = present), the subscript/coefficient *p* represents the position (0 = first administration, 1 = subsequent administration), and the subscript *n* indicates that the term is allowed to vary across individuals. Please consult Table S1 for a description of all other terms, and how these terms are symbolized in the M*plus* scripts that follow.

|  |  |  |
| --- | --- | --- |
| Symbol in Article | Symbol in M*plus* Scripts | Description |
| **Variables** |  |  |
| Y | Y | observed outcome (e.g. reasoning test performance) |
| Fc | Fc | inferred "true score" in the comparison condition (e.g. the score that the subject would receive if he/she took the reasoning test in the sugar pill condition, naïve to previous measurement or treatment) |
| F | Fd | inferred causal effect = theoretical true score in manipulation condition - theoretical true score in the comparison condition (e.g. reasoning performance in medication condition - reasoning performance in sugar pill condition) |
| FT | Ft | inferred net effect of extraneous variables (e.g. history, maturation, reactivity, measurement error). T stands for Threat to internal validity. |
| *x* |  | a measured covariate (e.g. age) |
| **Parameters** |  |  |
| Fc | mFc | mean of the inferred "true score" in the comparison condition |
| F | mFd | mean of the inferred causal effect |
| FT | mFt | mean net effect of extraneous variables |
| 2Fc | s2Fc | between-person variance of the inferred "true score" in the comparison condition |
| 2F | s2Fd | between-person variance of the inferred causal effect |
| 2FT | s2Ft | between-person variance of the net effect of extraneous variables |
| c | scd | covariance between individual differences in true comparison condition performance and individual differences in the causal effect |
| c | sct | covariance between individual differences in true comparison condition performance and individual differences in the net effect of extraneous variables |
|  | sdt | covariance between individual differences in the causal effect and individual differences in the net effect of extraneous variables |
| *x*,c | sxc | covariance between a measured covariate and individual differences in true comparison condition performance |
| *x*, | sxd | covariance between a measured covariate and individual differences in the causal effect |
| *x*, | sxt | covariance between a measured covariate and individual differences in the net effect of extraneous variables |
| *w* | lYw | factor loading of test form w on true performance |
| *w* | mYw | intercept of test form *w* |
| 2*w* | s2Yw | residual variance of test form *w* |
|  | alpha | “carry-over” of the causal effect from having been exposed to the manipulation condition at a previous occasion |

Table S1. Glossary of symbols used in sample M*plus* scripts.

TITLE: Simple Within-Subjects Design

MONTECARLO:

NAMES ARE Y1 Y2 x;

NOBSERVATIONS = 200;

NGROUPS = 1;

NREPS = 100;

MODEL POPULATION:

Fc BY Y1@1;

Fd BY Y1@0;

Fc BY Y2@1;

Ft BY Y2@1;

Fd BY Y2@1;

Y1@.2; Y2@.2;

[Y1@0]; [Y2@0];

Fc\*1(s2c);

Ft\*.5(s2t);

Fd\*1(s2d);

[Ft\*1](mft);

[Fd\*2](mfd);

[Fc\*7](mFc);

Ft WITH Fc\*.3(sct);

fd WITH Fc\*.2(scd);

ft WITH Fd\*.3(std);

x\*1(s2x); [x\*0] (mx);

x WITH Fc\*.4(sxc);

x WITH Fd\*.4(sxd);

x WITH Ft\*.3(sxt);

MODEL:

Fc BY Y1@1;

Fc BY Y2@1;

Fd BY Y2@1;

Y1@0; Y2@0;

Fd WITH Fc\* (scd);

Fc\* (s2Fc);

Fd\* (s2Fd);

[Y1@0]; [Y2@0];

[Fc\*](mY1); [Fd\*](mFd);

x\*; [x\*];

x WITH Fc\*;

x WITH Fd\*;

TITLE: Simple Between-Subjects Design

MONTECARLO:

NAMES = y x;

NGROUPS = 2;

NOBS = 100 100;

NREPS = 100;

MODEL POPULATION:

Fc BY Y@1;

Fd BY Y@1;

Y@.2; [Y@0];

[Fc\*7](mfc); [Fd\*2](mfd);

Fc\*1(s2fc); Fd\*1(s2fd);

Fc WITH Fd@.2;

x\*1(s2x); [x\*0](mx);

x WITH Fc\*.4(sxc);

x WITH Fd\*.4(sxd);

MODEL POPULATION-g1:

[Fc\*7](mfc);

[Fd\*2](mfd);

Fd BY Y@0;

MODEL POPULATION-g2:

ANALYSIS:

MODEL:

Fc BY Y@1;

Fd BY Y@1;

Y@0; [Y@0];

[Fc\*](mfc); [Fd\*](mfd);

Fc\*(s2fc); Fd\*(s2fd);

Fc WITH Fd@0;

x\*(s2x); [x\*] (mx);

x WITH Fc\*(sxc);

x WITH Fd\*(sxd);

MODEL g1:

[Fc\*](mfc);

[Fd\*](mfd);

Fd BY Y@0;

MODEL g2:

TITLE: Between x Within Design

MONTECARLO:

NAMES ARE Y1 Y2 x;

NOBSERVATIONS = 100 100;

NGROUPS = 2;

NREPS = 100;

MODEL POPULATION:

Fc BY Y1@1;

Fc BY Y2@1;

Ft BY Y2@1;

Fd BY Y2@1;

Y1\*.2; Y2\*.2;

Fc\*1 (s2Fc);

Ft\*.5 (s2Ft);

Fd\*1 (s2Fd);

Ft WITH Fc\*.3 (sct);

Fd with Fc\*.2 (scd);

Ft WITH Fd\*.3 (sdt);

[Y1@0]; [Y2@0]; [Fc\*7](mFc); [Ft\*1](mFt); [Fd\*2](mFd);

x\*1(s2x); [x\*0] (mx);

x WITH Fc\*.4(sxc);

x WITH Fd\*.4(sxd);

x WITH Ft\*.3(sxt);

MODEL POPULATION-g1:

[Fc\*7](mFc); [Ft\*1](mFt); [Fd\*2](mFd);

Fd BY Y2@0;

MODEL POPULATION-g2:

ANALYSIS:

MODEL:

Fc BY Y1@1;

Fc BY Y2@1;

Ft BY Y2@1;

Fd BY Y2@1;

Y1@0; Y2@0;

Fc\* (s2Fc);

Ft\* (s2Ft);

Fd\* (s2Fd);

Ft with Fc\* (sct);

Fd with Fc\* (scd);

Ft WITH Fd@0;

[Y1@0]; [Y2@0]; [Fc\*](mFc); [Ft\*](mFt); [Fd\*](mFd);

x\*(s2x); [x\*](mx);

x WITH Fc\*(sxc);

x WITH Fd\*(sxd);

x WITH Ft\*(sxt);

MODEL g1:

[Fc\*](mFc); [Ft\*](mFt); [Fd\*](mFd);

Fd BY Y2@0;

MODEL g2:

TITLE: Common Test Equating for Experiments

MONTECARLO:

NAMES = Yd Ya Yb x;

NGROUPS = 2;

NOBS = 100 100;

NREPS = 100;

MODEL POPULATION:

Fc BY Yd\*.8(lYd);

Fc BY Ya\*1(lYa);

Fc BY Yb\*1.1(lYb);

Fd BY Ya\*1(lYa);

Fd BY Yb\*1.1(lYb);

Ya\*.2(s2Ya); Yb\*.2(s2Yb); Yd\*.2(s2Yd);

[Ya\*0]; [Yb\*-1](mYb); [Yd\*2](mYd);

Ft BY Ya\*1(lYa);

Ft BY Yb\*1.1(lYb);

Fc\*1(s2c); Ft\*.5(s2t); Fd\*1(s2d);

Ft WITH Fc\*.3(sct);

fd WITH Fc\*.2(scd);

ft WITH Fd\*.3(std);

[Ft\*1](mft); [Fd\*2](mfd); [Fc\*7](mfc);

x\*1(s2x); [x\*0] (mx);

x WITH Fc\*.4(sxc);

x WITH Fd\*.4(sxd);

x WITH Ft\*.3(sxt);

MODEL POPULATION-g1:

[Fd\*2](mfd); [Fc\*7](mFc);

[Ya\*0]; [Yb\*-1](mYb); [Yd\*2](mYd);

Fd BY Ya@0;

MODEL POPULATION-g2:

Fd BY Yb@0;

ANALYSIS:

MODEL:

Fc BY Yd\*(lYd);

Fc BY Ya@1(lYa);

Fc BY Yb\*(lYb);

Fd BY Ya@1(lYa);

Fd BY Yb\*(lYb);

Ya\*(s2Ya); Yb\*(s2Yb); Yd\*(s2Yd);

[Ya@0](mYa); [Yb\*](mYb); [Yd\*](mYd);

Fc\*(s2Fc); Fd\*(s2Fd);

Fd WITH Fc\*(scd);

[Fd\*](mfd); [Fc\*](mFc);

x\*(s2x); [x\*](mx);

x WITH Fc\*(sxc);

x WITH Fd\*(sxd);

MODEL g1:

[Fd\*](mFd); [Fc\*](mFc);

Fd BY Ya@0;

MODEL g2:

Fd BY Yb@0;

TITLE: Three-Group Repeated Measure Design

MONTECARLO:

NAMES = Y1 Y2 x;

NGROUPS = 3;

NOBS = 67 67 66;

NREPS = 100;

MODEL POPULATION:

Fc BY Y1@1;

Fd BY Y1@1;

Fc BY Y2@1;

Ft BY Y2@1;

Fd BY Y2@1;

Y1@.2; Y2@.2;

[Y1@0]; [Y2@0];

Fc\*1(s2c);

Ft\*.5(s2t);

Fd\*1(s2d);

Ft WITH Fc\*.3(sct);

fd WITH Fc\*.2(scd);

ft WITH Fd\*.3(std);

[Ft\*1](mft);

[Fd\*2](mfd);

[Fc\*7](mfc);

x\*1(s2x); [x\*0](mx);

x WITH Fc\*.4(sxc);

x WITH Fd\*.4(sxd);

x WITH Ft\*.3(sxt);

MODEL POPULATION-g1:

[Ft\*1](mft);

[Fd\*2](mfd);

[Fc\*7](mfc);

Fd BY Y1@0;

Fd BY Y2@0;

MODEL POPULATION-g2:

Fd BY Y1@0;

MODEL POPULATION-g3:

Fd BY Y2@0;

ANALYSIS:

MODEL:

Fc BY Y1@1;

Fd BY Y1@1;

Fc BY Y2@1;

Ft BY Y2@1;

Fd BY Y2@1;

Y1@0; Y2@0;

[Y1@0]; [Y2@0];

Fc\*(s20);

Ft\*(s2t);

Fd\*(s2d);

Ft WITH Fc\*(sct);

fd WITH Fc\*(scd);

ft WITH Fd\*(std);

[Ft\*](mft);

[Fd\*](mfd);

[Fc\*](mfc);

x\*(vx); [x\*] (mx);

x WITH Fc\*(sxc);

x WITH Fd\*(sxd);

x with Ft(sxt);

MODEL g1:

[Ft\*](mft);

[Fd\*](mfd);

[Fc\*](mfc);

Fd BY Y1@0;

Fd BY Y2@0;

MODEL g2:

Fd BY Y1@0;

MODEL g3:

Fd BY Y2\*(alpha);

TITLE: Three-Group Non-Repeated Measures Design

MONTECARLO:

NAMES = Y1 Y2 x;

NGROUPS = 3;

NOBS = 67 67 66;

NREPS = 100;

MODEL POPULATION:

Fc BY Y1@1;

Fd BY Y1@1;

Fc BY Y2@1;

Ft BY Y2@1;

Fd BY Y2@1;

Y1@.2; Y2@.2;

[Y1@0]; [Y2@0];

[Fc\*7](mFc); [Ft\*1](mft); [Fd\*2](mfd);

Fc\*1(s2c); Ft\*.5(s2t); Fd\*1(s2d);

Ft WITH Fc\*.3(sct);

fd WITH Fc\*.2(scd);

ft WITH Fd\*.3(std);

x\*1(s2x); [x\*0](mx);

x WITH Fc\*.4(sxc);

x WITH Fd\*.4(sxd);

x WITH Ft\*.3(sxt);

MODEL POPULATION-g1:

[Ft\*1](mft); [Fd\*2](mfd); [Fc\*7](mFc);

Fc BY Y1@1;!(la);

Fd BY Y1@0;

Fc BY Y2\*1.1(lb);

Ft BY Y2\*1.1(lb);

Fd BY Y2@0;

[Y1@0];!(ia);

[Y2\*-1](ib);

MODEL POPULATION-g2:

Fc BY Y1\*1.1(lb);

Fd BY Y1@0;

Fc BY Y2@1;!(la);

Ft BY Y2@1;!(la);

Fd BY Y2@1;!(la);

[Y1\*-1](ib);

[Y2@0];!(ia);

MODEL POPULATION-g3:

Fc BY Y1@1;!(la);

Fd BY Y1@1;!(la);

Fc BY Y2\*1.1(lb);

Ft BY Y2\*1.1(lb);

Fd BY Y2@0;

[Y1@0];!(ia);

[Y2\*-1](ib);

ANALYSIS:

MODEL:

Fc BY Y1\*;

Fd BY Y1\*;

Fc BY Y2\*;

Ft BY Y2\*;

Fd BY Y2\*;

Y1@0; Y2@0;

[Y1\*]; [Y2\*];

[Fc\*](mFc); [Ft\*](mft); [Fd\*](mfd);

Fc\*(s2c); Ft\*(s2t); Fd\*1(s2d);

Ft WITH Fc\*(sct);

Fd WITH Fc\*(scd);

Ft WITH Fd\*(std);

x\*(s2x); [x\*] (mx);

x WITH Fc\*(sxc);

x WITH Fd\*(sxd);

x with Ft\*(sxt);

MODEL g1:

[Ft\*](mft);

[Fd\*](mfd);

[Fc\*](mFc);

Fc BY Y1@1;

Fd BY Y1@0;

Fc BY Y2\*(lb);

Ft BY Y2\*(lb);

Fd BY Y2@0;

[Y1@0];!(ia);

[Y2\*](ib);

MODEL g2:

Fc BY Y1\*(lb);

Fd BY Y1@0;

Fc BY Y2@1;

Ft BY Y2@1;

Fd BY Y2@1;

[Y1\*](ib);

[Y2@0];

MODEL g3:

Fc BY Y1@1;

Fd BY Y1@1;

Fc BY Y2\*(lb);

Ft BY Y2\*(lb);

Fd BY Y2\*(carryover);

[Y1@0];

[Y2\*6](ib);

MODEL CONSTRAINT:

NEW(alpha);

carryover = alpha\*lb;